home *** CD-ROM | disk | FTP | other *** search
/ PCGUIA 114 / PC Guia 114.iso / Software / Produtividade / Apache 2.0.52 / apache_2.0.52-win32-x86-no_ssl.msi / Data.Cab / F278606_hhp.xsl < prev    next >
Encoding:
Extensible Markup Language  |  2004-06-20  |  14.0 KB  |  316 lines
  1. <?xml version="1.0"?>
  2.  
  3. <!--
  4.  Copyright 2003-2004 The Apache Software Foundation
  5.  
  6.  Licensed under the Apache License, Version 2.0 (the "License");
  7.  you may not use this file except in compliance with the License.
  8.  You may obtain a copy of the License at
  9.  
  10.      http://www.apache.org/licenses/LICENSE-2.0
  11.  
  12.  Unless required by applicable law or agreed to in writing, software
  13.  distributed under the License is distributed on an "AS IS" BASIS,
  14.  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15.  See the License for the specific language governing permissions and
  16.  limitations under the License.
  17. -->
  18.  
  19. <!DOCTYPE xsl:stylesheet [
  20.     <!ENTITY lf SYSTEM "../xsl/util/lf.xml">
  21. ]>
  22. <xsl:stylesheet version="1.0"
  23.               xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  24.                   xmlns="">
  25.  
  26. <!-- the accompanying server version -->
  27. <xsl:param name="httpd.version" select="'generic'" />
  28.  
  29. <!-- create nodeset for referencing later                                 -->
  30. <xsl:variable name="htmlhelp.def" select="document('')/xsl:stylesheet
  31.                                         /xsl:template[@name='htmlhelp.def']" />
  32.  
  33. <!-- ==================================================================== -->
  34. <!-- <sitemap>                                                            -->
  35. <!-- Create CHM project file from sitemap                                 -->
  36. <!-- The file is an *.ini format text file                                -->
  37. <!-- ==================================================================== -->
  38. <xsl:template match="/sitemap">
  39.  
  40. <!-- static information                                               -->
  41. <!-- **************************************************************** -->
  42. <xsl:text>[OPTIONS]</xsl:text>&lf;
  43. <xsl:text>Binary TOC=No</xsl:text>&lf;
  44. <xsl:text>Compatibility=1.0</xsl:text>&lf;
  45.  
  46. <!-- resulting filename -->
  47. <xsl:text>Compiled file=httpd-docs-</xsl:text>
  48. <xsl:value-of select="$httpd.version" />
  49. <xsl:text>.</xsl:text>
  50. <xsl:value-of select="$doclang" />
  51. <xsl:text>.chm</xsl:text>&lf;
  52.  
  53. <xsl:text>Contents file=toc.hhc</xsl:text>&lf;
  54. <xsl:text>Default Window=Main</xsl:text>&lf;
  55. <xsl:text>Default topic=index.html</xsl:text>&lf;
  56.  
  57. <!-- compiler related -->
  58. <xsl:text>Display compile progress=Yes</xsl:text>&lf;
  59. <xsl:text>Enhanced decompilation=Yes</xsl:text>&lf;
  60.  
  61. <!-- search related -->
  62. <xsl:text>Full-text search=Yes</xsl:text>&lf;
  63. <xsl:text>Language=</xsl:text>
  64. <xsl:value-of select="$hhp-lang" />&lf;
  65.  
  66. <!-- title of the help file -->
  67. <xsl:text>Title=</xsl:text>
  68. <xsl:value-of select="normalize-space($message[@id='apachehttpserver'])"/>&lf;&lf;
  69.  
  70. <!-- main window definition -->
  71. <xsl:text>[WINDOWS]</xsl:text>&lf;
  72. <xsl:text>Main=</xsl:text>
  73.  
  74. <!-- title -->
  75. <xsl:text>"</xsl:text>
  76. <xsl:value-of select="normalize-space($message[@id='apachehttpserver'])"/>
  77. <xsl:text>",</xsl:text>
  78.  
  79. <!-- toc file -->
  80. <xsl:text>"toc.hhc",</xsl:text>
  81.  
  82. <!-- index file (currently none) -->
  83. <xsl:text>,</xsl:text>
  84.  
  85. <!-- default file (startup) -->
  86. <xsl:text>"index.html",</xsl:text>
  87.  
  88. <!-- Home button file -->
  89. <xsl:text>"index.html",</xsl:text>
  90.  
  91. <!-- Jump 1 url, text -->
  92. <xsl:text>,,</xsl:text>
  93.  
  94. <!-- Jump 2 url, text -->
  95. <xsl:text>,,</xsl:text>
  96.  
  97. <!-- navigation pane style (0x1e357e) -->
  98. <xsl:call-template name="helper.number2hex">
  99.     <xsl:with-param name="number" select="sum($htmlhelp.def/navigation/style
  100.                                               [@selected='yes'])" />
  101. </xsl:call-template>
  102. <xsl:text>,</xsl:text>
  103.  
  104. <!-- navigation pane initial width (px) -->
  105. <xsl:text>180,</xsl:text>
  106.  
  107. <!-- button mask -->
  108. <xsl:call-template name="helper.number2hex">
  109.     <xsl:with-param name="number" select="sum($htmlhelp.def/buttons/button
  110.                                               [@visible='yes'])" />
  111. </xsl:call-template>
  112. <xsl:text>,</xsl:text>
  113.  
  114. <!-- Initial Position [Left, Top, Right, Bottom] -->
  115. <xsl:text>[0,0,600,380],</xsl:text>
  116.  
  117. <!-- window style -->
  118. <xsl:call-template name="helper.number2hex">
  119.     <xsl:with-param name="result" select="'0000'" /> <!-- << 16 -->
  120.     <xsl:with-param name="number" select="sum($htmlhelp.def/windowstyle/style
  121.                                               [@selected='yes'])" />
  122. </xsl:call-template>
  123. <xsl:text>,</xsl:text>
  124.  
  125. <!-- extended style -->
  126. <xsl:text>,</xsl:text>
  127.  
  128. <!-- flag: navigation pane initial closed (=1) -->
  129. <xsl:text>,</xsl:text>
  130.  
  131. <!-- unknown, default pane, unknown, unknown -->
  132. <xsl:text>,,,0</xsl:text>&lf;&lf;
  133.  
  134. <!-- file list                                                        -->
  135. <!-- **************************************************************** -->
  136. <xsl:text>[FILES]</xsl:text>&lf;
  137.  
  138. <!-- not automatically sucked in. (because only @import()ed) -->
  139. <xsl:text>style\css\manual.css</xsl:text>&lf;
  140. <xsl:text>style\css\manual-loose-100pc.css</xsl:text>&lf;
  141.  
  142. <!-- include project file itself for easier recompiling -->
  143. <xsl:text>manual.hhp</xsl:text>&lf;
  144.  
  145. <!-- and now all sitemap-listed files -->
  146. <xsl:for-each select="category">
  147.     <xsl:apply-templates select="page[@href]" />
  148.     <xsl:if test="@id = 'modules'">
  149.         <xsl:apply-templates select="document($allmodules)/modulefilelist
  150.                                      /modulefile" />
  151.     </xsl:if>
  152. </xsl:for-each>&lf;
  153. </xsl:template>
  154. <!-- /sitemap -->
  155.  
  156.  
  157. <!-- ==================================================================== -->
  158. <!-- files referenced in sitemap                                          -->
  159. <!-- ==================================================================== -->
  160. <xsl:template match="category/page">
  161. <xsl:variable name="filename">
  162.     <xsl:choose>
  163.     <xsl:when test="contains(@href, '#') and substring(@href,
  164.                     string-length(substring-before(@href, '#')), 1) = '/'">
  165.         <xsl:value-of select="substring-before(@href, '#')" />
  166.         <xsl:text>index.html</xsl:text>
  167.     </xsl:when>
  168.     <xsl:when test="substring(@href, string-length(@href), 1) = '/'">
  169.         <xsl:value-of select="@href"/>
  170.         <xsl:text>index.html</xsl:text>
  171.     </xsl:when>
  172.     <xsl:otherwise>
  173.         <xsl:value-of select="@href"/>
  174.     </xsl:otherwise>
  175.     </xsl:choose>
  176. </xsl:variable>
  177.  
  178. <xsl:value-of select="translate($filename, '/', '\')" />&lf;
  179. </xsl:template>
  180. <!-- /page[@href] -->
  181.  
  182.  
  183. <!-- ==================================================================== -->
  184. <!-- list module files                                                    -->
  185. <!-- ==================================================================== -->
  186. <xsl:template match="modulefilelist/modulefile">
  187. <xsl:text>mod\</xsl:text>
  188. <xsl:value-of select="substring-before(normalize-space(.), '.xml')" />
  189. <xsl:text>.html</xsl:text>&lf;
  190. </xsl:template>
  191. <!-- /modulefilelist/modulefile -->
  192.  
  193.  
  194. <!-- ==================================================================== -->
  195. <!-- convert number to its hexadecimal representation.                    -->
  196. <!-- I could not find a built-in function, so write our own ... *sigh*    -->
  197. <!-- ==================================================================== -->
  198. <xsl:template name="helper.number2hex">
  199. <xsl:param name="number" />
  200. <xsl:param name="result" />
  201.  
  202. <xsl:choose>
  203. <xsl:when test="number($number) > 0">
  204.     <xsl:call-template name="helper.number2hex">
  205.         <xsl:with-param name="number" select="floor(number($number) div 16)" />
  206.         <xsl:with-param name="result"
  207.             select="concat(substring('0123456789abcdef',
  208.                                      (number($number) mod 16) + 1, 1),
  209.                            $result)" />
  210.     </xsl:call-template>
  211. </xsl:when>
  212. <xsl:otherwise>
  213.     <!-- if zero, don't print anything. hh.exe (the viewer) seems to -->
  214.     <!-- prefer an empty value -->
  215.     <xsl:if test="string-length(translate($result, '0', '')) > 0">
  216.         <xsl:text>0x</xsl:text>
  217.         <xsl:value-of select="$result" />
  218.     </xsl:if>
  219. </xsl:otherwise>
  220. </xsl:choose>
  221. </xsl:template>
  222. <!-- /helper.number2hex -->
  223.  
  224.  
  225. <!-- ==================================================================== -->
  226. <!-- some of the values are derived from htmlhelp.h                       -->
  227. <!-- do NOT call this template, it's referenced automagically via         -->
  228. <!-- document() function and acts as simple data container.               -->
  229. <!--                                                                      -->
  230. <!-- Hints: 'ni' means 'not implemented' (by the help viewer)             -->
  231. <!--        'ns' means 'not useful for standalone help file'              -->
  232. <!-- ==================================================================== -->
  233. <xsl:template name="htmlhelp.def">
  234. <navigation>
  235.     <style               >        1</style> <!-- auto hide nav. pane   <<  0 -->
  236.     <style               >        2</style> <!-- ns: topmost window    <<  1 -->
  237.     <style               >        4</style> <!-- ns: no title bar      <<  2 -->
  238.     <style               >        8</style> <!-- ns: no win. style     <<  3 -->
  239.     <style               >       16</style> <!-- ns: no ext. style     <<  4 -->
  240.     <style selected="yes">       32</style> <!-- use tri-pane win.     <<  5 -->
  241.     <style               >       64</style> <!-- no toolbar text       <<  6 -->
  242.     <style               >      128</style> <!-- ns: send WM_QUIT      <<  7 -->
  243.     <style selected="yes">      256</style> <!-- toc auto sync         <<  8 -->
  244.     <style               >      512</style> <!-- ns: send track. not.  <<  9 -->
  245.     <style selected="yes">     1024</style> <!-- search tab            << 10 -->
  246.     <style               >     2048</style> <!-- ni(?): history tab    << 11 -->
  247.     <style selected="yes">     4096</style> <!-- favorites tab         << 12 -->
  248.     <style               >     8192</style> <!-- ni(?): title sync     << 13 -->
  249.     <style               >    16384</style> <!-- nav. only             << 14 -->
  250.     <style               >    32768</style> <!-- no toolbar            << 15 -->
  251.     <style selected="yes">    65536</style> <!-- show menu             << 16 -->
  252.     <style selected="yes">   131072</style> <!-- advanced search       << 17 -->
  253.     <style selected="yes">   262144</style> <!-- safe user's win. size << 18 -->
  254.     <style               >   524288</style> <!-- custom tab 1          << 19 -->
  255.     <style               >  1048576</style> <!-- custom tab 2          << 20 -->
  256.     <style               >  2097152</style> <!-- custom tab 3          << 21 -->
  257.     <style               >  4194304</style> <!-- custom tab 4          << 22 -->
  258.     <style               >  8388608</style> <!-- custom tab 5          << 23 -->
  259.     <style               > 16777216</style> <!-- custom tab 6          << 24 -->
  260.     <style               > 33554432</style> <!-- custom tab 7          << 25 -->
  261.     <style               > 67108864</style> <!-- custom tab 8          << 26 -->
  262.     <style               >134217728</style> <!-- custom tab 9          << 27 -->
  263.     <style               >268435456</style> <!-- window has margin (?) << 28 -->
  264. </navigation>
  265.  
  266. <buttons>
  267.     <button visible="yes">      2</button> <!-- expand/contract   <<  1 -->
  268.     <button visible="yes">      4</button> <!-- back              <<  2 -->
  269.     <button visible="yes">      8</button> <!-- forward           <<  3 -->
  270.     <button visible="yes">     16</button> <!-- Stop              <<  4 -->
  271.     <button              >     32</button> <!-- Refresh           <<  5 -->
  272.     <button visible="yes">     64</button> <!-- Home              <<  6 -->
  273.     <button              >    128</button> <!-- ni: browse fwd    <<  7 -->
  274.     <button              >    256</button> <!-- ni: browse back   <<  8 -->
  275.     <button              >    512</button> <!-- ni: notes         <<  9 -->
  276.     <button              >   1024</button> <!-- ni: contents      << 10 -->
  277.     <button visible="yes">   2048</button> <!-- Sync TOC          << 11 -->
  278.     <button visible="yes">   4096</button> <!-- Options           << 12 -->
  279.     <button visible="yes">   8192</button> <!-- Print             << 13 -->
  280.     <button              >  16384</button> <!-- ni: index         << 14 -->
  281.     <button              >  32768</button> <!-- ni: search        << 15 -->
  282.     <button              >  65536</button> <!-- ni: history       << 16 -->
  283.     <button              > 131072</button> <!-- ni: favorites     << 17 -->
  284.     <button              > 262144</button> <!-- Jump 1            << 18 -->
  285.     <button              > 524288</button> <!-- Jump 2            << 19 -->
  286.     <button visible="yes">1048576</button> <!-- (Font) Zoom       << 20 -->
  287.     <!-- the following work only with binary toc, which unfortunately   -->
  288.     <!-- seems to eat the different icons ...                           -->
  289.     <button              >2097152</button> <!-- TOC next          << 21 -->
  290.     <button              >4194304</button> <!-- TOC prev          << 22 -->
  291. </buttons>
  292.  
  293. <windowstyle>
  294.     <!-- all the stuff is additionally shifted << 16 (by the caller) -->
  295.     <style selected="yes">    1</style> <!-- maximize box     <<  0 -->
  296.     <style selected="yes">    2</style> <!-- minimize box     <<  1 -->
  297.     <style selected="yes">    4</style> <!-- thick frame      <<  2 -->
  298.     <style selected="yes">    8</style> <!-- system menu      <<  3 -->
  299.     <style               >   16</style> <!-- horiz. scroll    <<  4 -->
  300.     <style               >   32</style> <!-- vertic. scroll   <<  5 -->
  301.     <style selected="yes">   64</style> <!-- dialog frame     <<  6 -->
  302.     <style selected="yes">  128</style> <!-- border           <<  7 -->
  303.     <style selected="yes">  256</style> <!-- maximize         <<  8 -->
  304.     <style               >  512</style> <!-- clip child win.  <<  9 -->
  305.     <style               > 1024</style> <!-- clip sibl. win.  << 10 -->
  306.     <style               > 2048</style> <!-- disabled         << 11 -->
  307.     <style selected="yes"> 4096</style> <!-- visible          << 12 -->
  308.     <style selected="yes"> 8192</style> <!-- minimize         << 13 -->
  309.     <style               >16384</style> <!-- child window     << 14 -->
  310.     <style               >32768</style> <!-- pop-up           << 15 -->
  311. </windowstyle>
  312. </xsl:template>
  313. <!-- /htmlhelp.def -->
  314.  
  315. </xsl:stylesheet>
  316.